home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Amiga Magazin: Amiga-CD 1996 May & June
/
Amiga-CD 1996 #5-6.iso
/
demos
/
finaldata
/
hdinstall
< prev
next >
Wrap
Text File
|
1996-03-22
|
8KB
|
253 lines
;;
;; $Filename: HDInstall $
;; $Date: 1994/10/24 11:37:51 $
;; $Revision: 1.2 $
;;
(set is_update 0)
(set @user-level 1) ; force to use average mode
(complete 0)
(set FD_dest
(askdir
(prompt "In welcher Disk/Schublade soll Final Data erstellt werden?")
(help "Das Installationsprogramm erstellt die Schublade "
"\"FinalData_D\" in diesem Verzeichnis. Alle Dateien von "
"Final Data werden in dieses Verzeichnis kopiert. \n\n"
"Tip für erfahrene Benutzer:\n"
"FinalData kann auch in ein anderes Verzeichnis "
"verschoben werden, wenn die Unterverzeichnisse:\n"
"FDFiles, FDFonts und FDLibs\n"
"ebenfalls an die neue Position des Programms verschoben "
"werden.")
(default @default-dest)
)
)
; Check if this is an update
; the FDLibs directory is a tell-tale sign
; that FD is already installed here
(if (exists (tackon FD_dest "FDLibs"))
(set is_update 1)
( (if (exists (tackon FD_dest "FinalData_D"))
(set is_update 1)
(makedir (tackon FD_dest "FinalData_D") (infos))
)
(set FD_dest (tackon FD_dest "FinalData_D"))
)
)
(set @default-dest FD_dest)
(set disk_space (getdiskspace FD_dest))
(set disk_space_needed 500000)
(if (AND (< disk_space disk_space_needed) (NOT is_update))
(
(set answer1
(askbool
(prompt "Auf dem Laufwerk ist möglicherweise nicht "
"genügend Platz für die Installation von "
"\"Final Data\". Trotzdem fortsetzen?")
(help "Final Data benötigt für die vollständige "
"Installation ca. 0,5 MegaByte freien Speicherplatz auf "
"der Disk. Wenn Final Data auf dieser Partition "
"bereits installiert ist, können Sie die Installation "
"fortsetzen. Andernfalls drücken Sie ABBRUCH "
"oder NEIN und schaffen danach entweder Platz "
"auf dieser Partition oder wählen eine andere "
"Partition für die Installation aus.")
)
)
(if (NOT answer1)
(abort "Installation von Final Data abgebrochen. Zu wenig "
"Speicherplatz auf dem Datenträger \""
(getdevice @default-dest)
"\"."
)
)
)
)
; Allow updating user to select what they want updated
(if is_update
; YES - already installed
(set install_options
(askoptions
(prompt "Welche Komponenten sollen aktualisiert werden?")
(help @askoptions-help)
(choices
"Final Data - Programm"
"ARexx-Makros"
"Beispieldateien"
"Systemdateien"
"Systembibliotheken"
"Systemschriftarten")
(default 25) ; default to 0001-1001 = (1)Program, (8)Sys Files and (16)Libraries
)
)
; NO - First time install
(set install_options 63) ; hex 3F - 0011-1111 - all six options on
)
(set error 0)
; Installing Files from FDProgram
(if (IN install_options 0 1 2 3 4 5)
(
; -----------------
; Copy the More program to the hard drive
; so everyone is guaranteed to have it.
; -----------------
(if (NOT is_update)
(copyfiles
(source "Amiga_1996_5:Demos/FinalData/More")
(dest FD_dest)
)
)
; -----------------
; If installing/updating the program
; -----------------
(if (IN install_options 0)
(
; ----- COPY the Final Data program over
(working "Final Data - Programm wird von der Diskette "
"FDProgram installiert.")
(copyfiles
(source "Amiga_1996_5:Demos/FinalData/FinalData")
(dest FD_dest)
)
; ----- COPY the Final Data .info if the icon doesn't exists
(if (NOT (exists (tackon FD_dest "FinalData.info")))
(copyfiles
(source "Amiga_1996_5:Demos/FinalData/FinalData.info")
(dest FD_dest)
)
)
)
)
(complete 50)
; -----------------
; Installing FDMacros
; -----------------
(if (IN install_options 1)
(
; ----- CREATE FDMacros if it doesn't exist.
(if (NOT (exists (tackon FD_dest "FDMacros")))
(
(makedir (tackon FD_dest "FDMacros") (infos))
)
)
(working "ARexx-Makros werden von der Diskette "
"FDProgram installiert.")
(copyfiles
(source "Amiga_1996_5:Demos/FinalData/FDMacros")
(dest (tackon FD_dest "FDMacros"))
(all)
)
)
)
(complete 60)
; -----------------
; Installing FDData
; -----------------
(if (IN install_options 2)
(
; If FDData doesn't exist, create it.
(if (NOT (exists (tackon FD_dest "FDData")))
(
(makedir (tackon FD_dest "FDData") (infos))
)
)
(working "Beispieldateien werden von der Diskette "
"FDProgram installiert.")
(copyfiles
(source "Amiga_1996_5:Demos/FinalData/FDData")
(dest (tackon FD_dest "FDData"))
(all)
)
)
)
(complete 70)
; -----------------
; Installing FDFiles (make dir, do not copy .prefs)
; -----------------
(if (IN install_options 3)
(
; If FDFiles doesn't exist, create it.
(if (NOT (exists (tackon FD_dest "FDFiles")))
(
(working "Systemdateien werden von der Diskette "
"FDProgram installiert.")
(makedir (tackon FD_dest "FDFiles") (infos))
)
)
)
)
(complete 80)
; -----------------
; Installing FDLibs
; -----------------
(if (IN install_options 4)
(
; If FDLibs doesn't exist, create it.
(if (NOT (exists (tackon FD_dest "FDLibs")))
(
(makedir (tackon FD_dest "FDLibs") (infos))
)
)
(working "Systembibliotheken werden von der Diskette "
"FDProgram installiert.")
(if (< (/ (getversion) 65536) 37)
(copyfiles
(source "Amiga_1996_5:Demos/FinalData/FDLibs/iffparse.library")
(dest (tackon FD_dest "FDLibs"))
(files)
)
)
(copyfiles
(source "Amiga_1996_5:Demos/FinalData/FDLibs/fcswlib.library")
(dest (tackon FD_dest "FDLibs"))
(files)
)
)
)
(complete 90)
; -----------------
; Installing FDFonts
; -----------------
(if (IN install_options 5)
(
; If FDFonts doesn't exist, create it.
(if (NOT (exists (tackon FD_dest "FDFonts")))
(
(makedir (tackon FD_dest "FDFonts") (infos))
)
)
(working "Systemschriftarten werden von der Diskette "
"FDProgram installiert.")
(copyfiles
(source "Amiga_1996_5:Demos/FinalData/FDFonts")
(dest (tackon FD_dest "FDFonts"))
(all)
)
(run ("Avail FLUSH"))
)
)
)
)
(complete 100)
(exit)